Selenium-Remote-Driver/at/legacy.test

use strict;
use warnings;

use Cwd qw{abs_path};
use FindBin;

use Test::More;
use Test::Fatal;
use Test::Deep;

use Selenium::Remote::Driver;
use Selenium::Remote::WDKeys;

my $driver = Selenium::Remote::Driver->new(
    remote_server_addr => '10.17.64.252',
    port => 4444,
    browser_name => 'firefox',
    accept_ssl_certs => 1,
);
isa_ok($driver,'Selenium::Remote::Driver',"Can get new S::R::D with WebDriver3");

$driver->debug_on();

is($driver->get_capabilities()->{browserName},'firefox',"Can get Capabilities correctly (WD2)");
my $sessions = $driver->get_sessions();
is(scalar(@$sessions),1,"Can fall back to selenium2 to list sessions");

ok($driver->status()->{build}->{version},"status reports OK (WD2)");

#TODO do something about available_engines

is( exception { $driver->set_timeout('page load',10000) },  undef, "WD2 set_timeout pageload OK");
is( exception { $driver->set_timeout('script',10000) },     undef, "WD2 set_timeout script OK");
is( exception { $driver->set_timeout('implicit',10000) },   undef, "WD2 set_timeout implicit OK");
is( exception { $driver->set_async_script_timeout(20000) }, undef, "WD2 set_async_script_timeout OK");
is( exception { $driver->set_implicit_wait_timeout(5000) }, undef, "WD2 set_implicit_wait_timeout OK");

my $loc = abs_path("$FindBin::Bin/test.html");
my $local_loc = $driver->upload_file($loc);
note $local_loc;

ok($driver->get("file://$local_loc"),"Can load a web page (WD2)");

is($driver->get_alert_text(),"BEEE DOOO","get_alert_text works (WD2)");
is(exception { $driver->dismiss_alert() }, undef, "alert can be dismissed (WD2)");

#This sucker wants "value" instead of "text" like in legacy
ok($driver->send_keys_to_prompt("HORGLE"),"send_keys_to_prompt works (WD2)");
is(exception { $driver->accept_alert() }, undef, "alert can be accepted (WD2)");

my $handle = $driver->get_current_window_handle();
ok($handle,"Got a window handle (WD2)");
cmp_bag($driver->get_window_handles(),[$handle],"Can list window handles (WD2)");

my $sz = $driver->get_window_size();
ok(defined $sz->{height},"get_window_size works (WD2)");
ok(defined $sz->{width},"get window size works (WD2)");
my $pos = $driver->get_window_position();
ok(defined $pos->{x},"get_window_size works (WD2)");
ok(defined $pos->{y},"get window size works (WD2)");

like($driver->get_current_url(),qr/test.html$/,"get_current_url works (WD2)");
like($driver->get_title(),qr/test/i,"get_title works (WD2)");

my $otherloc = abs_path("$FindBin::Bin/other.html");
my $other_local_loc = $driver->upload_file($otherloc);
note $other_local_loc;

$driver->get("file://$other_local_loc");
$driver->go_back();
$driver->dismiss_alert();
$driver->dismiss_alert();
like($driver->get_title(),qr/test/i,"go_back works (WD2)");

$driver->go_forward();
like($driver->get_page_source(),qr/ZIPPY/,"go_forward & get_page_source works (WD2)");
is(exception { $driver->refresh() }, undef, "refresh works (WD2)");
$driver->go_back();
$driver->dismiss_alert();
$driver->dismiss_alert();

#TODO execute_*_script testing

ok($driver->screenshot(),"can get base64'd whole page screenshot (WD2)");

isa_ok($driver->find_element('red','class'),"Selenium::Remote::WebElement");
isa_ok($driver->find_element('text','name'),"Selenium::Remote::WebElement");
isa_ok($driver->find_element('Test Link', 'link_text'),"Selenium::Remote::WebElement");
isa_ok($driver->find_element('Test', 'partial_link_text'),"Selenium::Remote::WebElement");

is(scalar(@{$driver->find_elements('red','class')}),2,"can find multiple elements correctly");

my $lem = $driver->find_element('body', 'tag_name');
isa_ok($driver->find_child_element($lem, 'red','class'),"Selenium::Remote::WebElement");
isa_ok($driver->find_child_element($lem, 'text','name'),"Selenium::Remote::WebElement");
isa_ok($driver->find_child_element($lem, 'Test Link', 'link_text'),"Selenium::Remote::WebElement");
isa_ok($driver->find_child_element($lem, 'Test', 'partial_link_text'),"Selenium::Remote::WebElement");

$lem = $driver->find_element('form','tag_name');
is(scalar(@{$driver->find_child_elements($lem,'./*')}),6,"can find child elements (WD2)");

isa_ok($driver->get_active_element(),"Selenium::Remote::WebElement");

TODO: {
    local $TODO = "These methods aren't supported on firefox";
    is(exception { $driver->cache_status() },undef, "cache_status works in WD2");
    is(exception {
        $driver->set_geolocation(location => {
               latitude  => 40.714353,
               longitude => -74.005973,
               altitude  => 0.056747
        });
    }, undef, "set_geolocation works in WD2");
    is(exception { $driver->get_geolocation() }, undef, "get_geolocation works in WD2");
    is(exception { $driver->set_orientation("LANDSCAPE") }, undef, "set_orientation works in WD2");
    is(exception { $driver->get_orientation() }, undef, "get_orientation works in WD2");
}

ok($driver->get_log('server'), "get_log fallback works");
ok( scalar(@{$driver->get_log_types()}),"can fallback for get_log_types");

like($driver->upload_file($otherloc),qr/other.html$/,"upload_file fallback works");

#Jinkies, this stuff is cool, it prints the selenium server help page @_@
#diag explain $driver->get_local_storage_item('whee');
#diag explain $driver->delete_local_storage_item('whee');

ok($driver->switch_to_frame($driver->find_element('frame', 'id')),"can switch to frame (WD2)");
ok($driver->switch_to_frame(),"can switch to parent frame (WD2 only)");

ok($driver->set_window_position(1,1),"can set window position (WD2)");
ok($driver->set_window_size(200,200),"can set window size (WD2)");

ok($driver->maximize_window(),"can maximize window (WD2)");

is(scalar(@{$driver->get_all_cookies()}),1,"can get cookie list (WD2)");
$driver->delete_all_cookies();
is(scalar(@{$driver->get_all_cookies()}),0,"can delete all cookies (WD2)");

ok($driver->mouse_move_to_location( element => $driver->find_element('a','tag_name')),"Can use mouse_move_to_location");
$driver->click();
my $handles = $driver->get_window_handles();
is(scalar(@$handles),2,"Can move to element and then click it correctly (WD2)");

$driver->switch_to_window($handles->[1]);
is(exception { $driver->close() }, undef, "Can close new window (WD2)");
cmp_bag($driver->get_window_handles,[$handles->[0]],"Correct window closed (WD2)");
$driver->switch_to_window($handles->[0]);

my $input = $driver->find_element('input','tag_name');
$driver->mouse_move_to_location( element => $input );
$driver->click();

#TODO pretty sure this isn't working right
SKIP: {
    skip("P.sure send_modifier is kind of screwed up",1);
    $driver->send_modifier('Shift','down');
}

$driver->send_keys_to_active_element('howdy',KEYS->{tab});
$input->send_keys('eee');
$driver->mouse_move_to_location( element => $driver->find_element('body','tag_name'));
$driver->click();

#XXX this has to be a BUG in the driver, the keys are getting thru
is($input->get_attribute('value'),'defaulthowdyeee',"element->get_attribute() works (WD2)");
is($input->get_attribute('value',1),'defaulthowdyeee',"element->get_attribute() second arg ignored (WD2)");
is($driver->execute_script(qq/ return document.querySelector('input').value /),'defaulthowdyeee',"execute_script works, and so does send_keys_to_active_element & element->send_keys (WD2)");
$input->clear();
is($input->get_attribute('value'),'',"clear() works (WD2)");

is(exception { $driver->button_down() },undef,"Can button down (WD2)");
is(exception { $driver->button_up() },undef,"Can button up (WD2)");

ok($driver->find_element('radio2','id')->is_selected(),"WD2 is_selected() works");
my $l1 = $driver->find_element('radio1','id');
SKIP: {
    skip "set_selected, toggle_element, is_selected looks broke", 1;
    $l1->set_selected();
    $l1->set_selected();
    ok($l1->is_selected(),"WD2 set_selected works");
    $l1->toggle();
    ok(!$l1->is_selected(),"WD2 toggle works: off");
    $l1->toggle();
    ok($l1->is_selected(),"WD2 toggle works: on");
}

my $l2 = $driver->find_element('hammertime','id');
is( $l2->is_enabled(),0,"is_enabled works (WD2)");
ok( $l2->get_element_location()->{x},"Can get element rect (WD2)");
ok( $l2->get_size()->{'height'}, "Size shim on rect works (WD2)");
is( $l2->get_tag_name(),'input',"get_tag_name works (WD2)");
is( exception { $l2->get_element_location_in_view() }, undef, "get_element_location_in_view not available in WD2");

is($driver->find_element('hidon','id')->is_displayed(),0,"is_displayed returns false for type=hidden elements");
is($driver->find_element('no-see-em','id')->is_displayed(),0,"is_displayed returns false for display=none");
is($driver->find_element('h1','tag_name')->get_text(),'Howdy Howdy Howdy', "get_text works (WD2)");

$driver->find_element('clickme','id')->click();
is(exception { $driver->dismiss_alert() }, undef, "Can click element (WD2)");

$driver->find_element('form','tag_name')->submit();
like($driver->get_page_source(),qr/File not found/,"elem submit() works (WD2)");

#Pretty sure this one has enough 'inertia' to not disappear all the sudden
$driver->get('http://w3.org/History.html');
$driver->add_cookie('foo','bar',undef,undef,0,0,time()+5000);
is(scalar(@{$driver->get_all_cookies()}),1,"can set cookie (WD2)");

$driver->delete_cookie_named('foo');
is(scalar(@{$driver->get_all_cookies()}),0,"can delete named cookies (WD2)");

is(exception { $driver->quit() }, undef, "Can quit (WD2)");

done_testing();